blob: 176213f5c86e45643ca01c5dc7c227ac3b793494 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
|
{ config, pkgs, ... }:
let
inherit (pkgs) iptables;
wireguardPort = 51820;
wireguardIPv4 = number: subnet: "10.123.10.${number}/${subnet}";
wireguardIPv6 = number: subnet: "fd0f:123::${number}/${subnet}";
wireguardInterface = "wg0";
externalInterface = "enp1s0";
peerIPs = peerNumber: [
(wireguardIPv4 peerNumber "32")
(wireguardIPv6 peerNumber "128")
];
peers = [
# mel
{
publicKey = "vnZoHXapCLLUhZ8A8R5W0iJ8LpWVLve29z41kkoT0BU=";
allowedIPs = peerIPs "2";
}
# andrei
{
publicKey = "qqU4uYImLfUohIwl4KBshPtTINFcs0JVALjbmwpfxRg=";
allowedIPs = peerIPs "3";
}
];
in
{
age.secrets.wireguard-private-key = {
file = ../secrets/wireguard-private-key.age;
};
# enable nat, to rename internal wireguard ips to external ip (w/ iptables)
networking = {
nat = {
enable = true;
internalInterfaces = [ wireguardInterface ];
inherit externalInterface;
};
firewall = {
allowedUDPPorts = [ wireguardPort ];
};
};
# enable kernel support for ipv6 forwarding
boot.kernel.sysctl = {
"net.ipv6.conf.all.forwarding" = 1;
"net.ipv6.conf.default.forwarding" = 1;
};
networking.wireguard.interfaces.${wireguardInterface} = {
inherit peers;
# ip address of server + subnet of network
ips = [
(wireguardIPv4 "1" "24")
(wireguardIPv6 "1" "112")
];
listenPort = wireguardPort;
# route wireguard traffic to the internet
# also requires clients to have dns set. (i think)
# to avoid, maybe? use wg-quick + dnsmasq?
postSetup = ''
${iptables}/bin/iptables -t nat -A POSTROUTING -s ${wireguardIPv4 "0" "24"} -o ${externalInterface} -j MASQUERADE
${iptables}/bin/ip6tables -t nat -A POSTROUTING -s ${wireguardIPv6 "0" "112"} -o ${externalInterface} -j MASQUERADE
'';
postShutdown = ''
${iptables}/bin/iptables -t nat -D POSTROUTING -s ${wireguardIPv4 "0" "24"} -o ${externalInterface} -j MASQUERADE
${iptables}/bin/ip6tables -t nat -D POSTROUTING -s ${wireguardIPv6 "0" "112"} -o ${externalInterface} -j MASQUERADE
'';
privateKeyFile = config.age.secrets.wireguard-private-key.path;
};
}
|
