blob: f4b3e4a726b848a45c2da54fb4d254166053c6f1 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
|
{
lib,
config,
pkgs,
self,
...
}:
let
inherit (lib)
mkIf
mkOption
mkEnableOption
types
;
inherit (pkgs) stdenv;
inherit (stdenv.hostPlatform) system;
cfg = config.services.specimen;
in
{
options.services.specimen = {
enable = mkEnableOption "specimen application";
package = mkOption {
type = types.package;
description = "specimen package to use.";
default = self.packages.${system}.default;
};
user = mkOption {
type = types.nonEmptyStr;
default = "specimen";
description = "user under which specimen will run.";
};
group = mkOption {
type = types.nonEmptyStr;
default = "specimen";
description = "group under which specimen will run.";
};
port = mkOption {
type = types.port;
default = 4444;
description = "port that specimen will listen on.";
};
listenAddress = mkOption {
type = types.str;
default = "0.0.0.0";
description = "address that specimen will listen on.";
};
openFirewall = mkOption {
type = types.bool;
default = false;
description = "open specimen port in firewall for incoming connections.";
};
nameSecret = mkOption {
type = types.attrs;
description = "secret from which specimen will take the name from.";
};
};
config = mkIf cfg.enable {
assertions = with builtins; [
{
assertion = hasAttr "path" cfg.nameSecret;
message = "name secret needs to include path";
}
{
assertion = hasAttr "file" cfg.nameSecret;
message = "name secret needs to include store file";
}
];
networking.firewall.allowedTCPPorts = mkIf cfg.openFirewall [ cfg.port ];
users.users.${cfg.user} = {
description = "specimen user";
group = cfg.group;
isSystemUser = true;
};
users.groups.${cfg.group} = { };
systemd.services.specimen = {
description = "specimen application service";
wantedBy = [ "multi-user.target" ];
wants = [ "network.target" ];
after = [ "network.target" ];
restartTriggers = [ cfg.nameSecret.file ];
serviceConfig = {
User = cfg.user;
Group = cfg.user;
Type = "exec";
Restart = "always";
ExecStart = "${cfg.package}/bin/specimen -address ${cfg.listenAddress} -port ${toString cfg.port} -name ${cfg.nameSecret.path}";
# a gigantic amount of hardening!!
# realistically this much wouldn't be necessary.
# mostly here to show off ;3
# for documentation, see: https://www.freedesktop.org/software/systemd/man/latest/systemd.exec.html
LockPersonality = true;
CapabilityBoundingSet = [ "" ];
DeviceAllow = [ "" ];
MemoryDenyWriteExecute = true;
NoNewPrivileges = true;
PrivateDevices = true;
PrivateTmp = true;
ProtectClock = true;
ProtectProc = "invisible";
ProtectControlGroups = true;
ProtectHome = true;
ProtectHostname = true;
ProtectKernelLogs = true;
ProtectKernelModules = true;
ProtectKernelTunables = true;
ProtectSystem = "strict";
RemoveIPC = true;
RestrictAddressFamilies = [
"AF_INET"
"AF_INET6"
];
RestrictNamespaces = true;
RestrictRealtime = true;
RestrictSUIDSGID = true;
SystemCallArchitectures = "native";
};
};
};
}
|
