index : network	this commit main
	renard network configurations... again...

summary refs log tree commit diff

log msg author committer range

path: root/pkgs/bluesky/pds

Mode	Name	Size
-rw-r--r--	package-lock.json	209894	log plain
-rw-r--r--	package.nix	2393	log plain

generated by cgit-pink 1.4.1 (git 2.36.1) at 2026-04-26 02:07:45 +0000

{
  me,
  pkgs,
  lib,
  self,
  ...
}:

let
  inherit (lib) mkIf mkMerge;

  bismuthCache = {
    substituters = [ "http://bismuth.serval-moth.ts.net:3000" ];
    trusted-public-keys = [ "bismuth-1:Fkyzfd9gfMUVKq/KfNClHaB2rUiAGtXTzYu96oZteKQ=" ];
  };

  useBismuthCache = false;
  # useBismuthCache = me.name != "bismuth";
in
{
  nix = {
    # enable lix implementation
    package = pkgs.lixPackageSets.stable.lix;

    # add compat scripts to the environment,
    # to allow nixos-option to find the configuration
    nixPath = [
      "nixpkgs=${self}/compat"
      "nixos-config=${self}/compat/nixos"
    ];

    settings = mkMerge [
      {
        experimental-features = [
          "flakes"
          "nix-command"
        ];
        trusted-users = [
          "mel"
        ];
        # usually my builders have faster connections
        builders-use-substitutes = true;
        # don't wait too long on caches that are down
        connect-timeout = 3;
        # yes nix, i know my flake is dirty!!!
        warn-dirty = false;
      }
      (mkIf useBismuthCache bismuthCache)
    ];

    distributedBuilds = true;
    buildMachines =
      let
        tailnet = n: "${n}.serval-moth.ts.net";

        defaults = {
          sshUser = "mel";
          systems = [
            "x86_64-linux"
            "i686-linux"
          ];
          supportedFeatures = [
            "kvm"
            "big-parallel"
            "nixos-test"
            "benchmark"
          ];
        };
      in
      lib.filter (m: m.hostName != me.name) [
        {
          hostName = tailnet "renard";
          maxJobs = 8;
          speedFactor = 2;
          publicHostKey = "c3NoLWVkMjU1MTkgQUFBQUMzTnphQzFsWkRJMU5URTVBQUFBSUovcURMNys4NiswSDZOa1BzL3c0R1lpV1F3VC80WUF4OU8ySjdzTGtLbWYgcm9vdEByZW5hcmQK";
          inherit (defaults) sshUser systems supportedFeatures;
        }
        {
          hostName = tailnet "lapin";
          maxJobs = 4;
          speedFactor = 1;
          publicHostKey = "c3NoLWVkMjU1MTkgQUFBQUMzTnphQzFsWkRJMU5URTVBQUFBSUdNRC9FTjl2OFlnSE91NFlHNzRRK3h2d2pDZHhiTUlaam5RY1VYaTBRaFogcm9vdEBsYXBpbgo=";
          systems = [ "aarch64-linux" ];
          inherit (defaults) sshUser supportedFeatures;
        }
      ];
  };
}