{
  me,
  lib,
  self,
  ...
}:

{
  nix = {
    # add compat scripts to the environment,
    # to allow nixos-option to find the configuration
    nixPath = [
      "nixpkgs=${self}/compat"
      "nixos-config=${self}/compat/nixos"
    ];

    settings = {
      experimental-features = [
        "flakes"
        "nix-command"
      ];
      trusted-users = [
        "mel"
      ];
      # usually my builders have faster connections
      builders-use-substitutes = true;
      # don't wait too long on caches that are down
      connect-timeout = 3;
      # yes nix, i know my flake is dirty!!!
      warn-dirty = false;
    };

    distributedBuilds = true;
    buildMachines =
      let
        tailnet = n: "${n}.serval-moth.ts.net";

        defaults = {
          sshUser = "mel";
          systems = [ "x86_64-linux" "i686-linux" ];
          supportedFeatures = [
            "kvm"
            "big-parallel"
            "nixos-test"
            "benchmark"
          ];
        };
      in
      lib.filter (m: m.hostName != me) [
        {
          hostName = tailnet "bismuth";
          maxJobs = 16;
          speedFactor = 8;
          publicHostKey = "c3NoLWVkMjU1MTkgQUFBQUMzTnphQzFsWkRJMU5URTVBQUFBSUFRUllWU0tXaDRldDFtNUxsd1RoWTNIeEdTRkM0NDkydmhwaWQ4WTJzcVogcm9vdEBCaXNtdXRoCg==";
          inherit (defaults) sshUser systems supportedFeatures;
        }
        {
          hostName = tailnet "corsac";
          maxJobs = 2;
          speedFactor = 1;
          publicHostKey = "c3NoLWVkMjU1MTkgQUFBQUMzTnphQzFsWkRJMU5URTVBQUFBSUh4Z2hWWDBPcStlSGtsZy9lN3MvcWhDOENLOFBMVWd2cExrMkc1M3hFaksgcm9vdEBjb3JzYWMK";
          inherit (defaults) sshUser systems supportedFeatures;
        }
        {
          hostName = tailnet "renard";
          maxJobs = 6;
          speedFactor = 3;
          publicHostKey = "c3NoLWVkMjU1MTkgQUFBQUMzTnphQzFsWkRJMU5URTVBQUFBSUovcURMNys4NiswSDZOa1BzL3c0R1lpV1F3VC80WUF4OU8ySjdzTGtLbWYgcm9vdEByZW5hcmQK";
          inherit (defaults) sshUser systems supportedFeatures;
        }
      ];
  };
}